home *** CD-ROM | disk | FTP | other *** search
/ SGI Developer Toolbox 6.1 / SGI Developer Toolbox 6.1 - Disc 4.iso / src / exampleCode / irix / scripts / rcs / ci-script next >
Encoding:
Text File  |  1994-08-02  |  3.0 KB  |  97 lines
  1. #! /bin/csh -f
  2. #
  3. # $Id: ci-script,v 1.2 1992/10/27 10:10:30 carlson Exp carlson $
  4. #
  5. # ci-script    Performs a ci on the file passed.
  6. #
  7. #    Added functionality includes:
  8. #    1. Always performs default options $opt (defined in this script).
  9. #    2. Performs options found in environment variable RCSOPTS.
  10. #    3. Passes arguments from command line to ci.
  11. #    4. Performs options found in file .rcsopts.
  12. #
  13. # Revision History:
  14. #    $Log: ci-script,v $
  15. # Revision 1.2  1992/10/27  10:10:30  carlson
  16. # When breaking out the options, break out three characters instead of
  17. #   just two to allow checking of just the character following the dash.
  18. # Remove default options that conflict with command line options.
  19. #
  20. # Revision 1.1  91/08/27  13:13:01  carlson
  21. # Initial revision
  22. # 
  23. #------------------------------------------------------------------------
  24. # Set default options for ci command here.
  25. #
  26. set opt = ( )
  27. if ( $?RCSOPTS ) then
  28.     set opt = ( $opt $RCSOPTS )
  29. endif
  30. if ( -e ./.rcsopts ) then
  31.     set x = ( `grep "^ci[     ]" ./.rcsopts` )
  32.     if ( $#x > 1 ) set opt = ( $opt $x[2-] )
  33. endif
  34.  
  35. #----
  36. # Scan for end of options in parameter list.  We need to do this to
  37. # find where the file names start.
  38. #
  39. # While scanning, do the following:
  40. #    1. Remove any duplicated options from $opt.
  41. #    2. Remove any default options that conflict with user-specified
  42. #       options on the command line.
  43. #
  44. # How it is done:
  45. #    1. set arg_chars to all of the characters in the argument separated
  46. #       with spaces (so they are separate and distinct.
  47. #    2. If the argument does not start with a '-', we are done so we
  48. #       quit the loop.
  49. #    3. If the argument is "--", then we are done but ci won't accept
  50. #       this form so we have to remove it from argv.
  51. #    ---
  52. #    4. Scan the default options for duplicate options or options that
  53. #       are contradictory.
  54. #        a. set opt_chars to all of the characters in the option
  55. #           separated with spaces (so they are separate and
  56. #           distinct).
  57. #        b. If the option does not start with a '-', we are done
  58. #           so we quit the loop.
  59. #        c. If the option character is the same as the argument
  60. #           character, remove the option.
  61. #        d. If the option character is a contradictory character
  62. #           to the argument, remove the option.
  63. #
  64. @ first = 1
  65.  
  66. while ( $first <= $#argv )
  67.     set arg_chars = ( `echo $argv[$first] | sed "s/\(.\)\(.\)\(.\)/\1 \2 \3/\\
  68. s/\(.\)\(.\)/\1 \2/"` )
  69.     if ( "$arg_chars[1]" != "-" ) break
  70.     if ( "$arg_chars[2]" == "-" ) then
  71.     set argv[$first]
  72.     break
  73.     endif
  74.     @ secnd = 1
  75.     while ( $secnd <= $#opt )
  76.     set opt_chars = ( `echo $opt[$secnd] | sed "s/\(.\)\(.\)\(.\)/\1 \2 \3/\\
  77. s/\(.\)\(.\)/\1 \2/"` )
  78.     if ( "$opt_chars[1]" != "-" ) break
  79.     if ( "$opt_chars[2]" == "$arg_chars[2]" ) set opt[$secnd]
  80.     if ( "$opt_chars[2]" == "u" && "$arg_chars[2]" == "l" ) \
  81.         set opt[$secnd]
  82.     if ( "$opt_chars[2]" == 'l' && "$arg_chars[2]" == "u" ) \
  83.         set opt[$secnd]
  84.     @ secnd = $secnd + 1
  85.     end
  86.     @ first=$first + 1
  87. end
  88.  
  89. #----
  90. # Check out files with arguments passed.
  91. #
  92. /usr/sbin/ci $opt $argv
  93.  
  94. ### Local Variables:
  95. ### auto-fill-hook: nil
  96. ### End:
  97.